PSPx форум - Просмотр сообщения отдельно - PKGi PS3 RUS MOD

ErikPshat · 07.01.2021, 01:01

Конвертер базы данных сайта NoPayStation для PKGi:

Написал конвертер базы данных сайта NoPlayStation..com в формат PKGi для PS3. Конвертировать можно файлы базы TSV вот этих форматов:

Батник проверяет правильность строки и её параметров. Все неверные значения помещаются в отдельные файлы по их параметрам. Так вы можете сразу увидеть в чём была в строке ошибка. Обычно, либо не хватает RAP-а, либо ссылка битая неверная и т.п..

Инструкция по использованию:

Скачайте и разархивируйте папку из архива: TSV_Converter_PS3.zip
Скачайте в эту папку утилиту wget.exe битности вашей системы:
- https://eternallybored.org/misc/wget/1.20.3/32/wget.exe (32-bit)
- https://eternallybored.org/misc/wget/1.20.3/64/wget.exe (64-bit)
Запускайте любой батник, который вам больше нравится:
- Parser NoPlayStation.bat - самый простой скрипт, работает очень быстро, за 10 секунд сконвертирует вам базу.
- Parser NoPlayStation SHA256.bat - батник тяжёлый, добавляет в конец каждой строки контрольную сумму SHA256, работает очень долго!
Забирайте потом готовую базу для PKGi в файле pkgi_games.txt и подкиньте его в папку программы: /dev_hdd0/game/NP00PKGI3/USRDIR/
Так же вы можете в батнике раскомментировать другие строчки для DLC/Theme/Avatar/Demo и сконвертировать для них базы.

Батник 1 быстрый:

@echo off
setlocal EnableDelayedExpansion
TITLE Database Parser NoPlayStation - http://nopaystation.com
mode con:cols=172
if exist pkgi_games_MISSING_URL.txt del \q pkgi_games_MISSING_URL.txt
if exist pkgi_games_MISSING_RAP.txt del \q pkgi_games_MISSING_RAP.txt
if exist pkgi_games_MISSING_CID.txt del \q pkgi_games_MISSING_CID.txt
if exist pkgi_games.txt del \q pkgi_games.txt

wget -O PS3_GAMES.tsv http://nopaystation.com/tsv/PS3_GAMES.tsv
::wget -O PS3_DLCS.tsv http://nopaystation.com/tsv/PS3_DLCS.tsv
::wget -O PS3_THEMES.tsv http://nopaystation.com/tsv/PS3_THEMES.tsv
::wget -O PS3_AVATARS.tsv http://nopaystation.com/tsv/PS3_AVATARS.tsv
::wget -O PS3_DEMOS.tsv http://nopaystation.com/tsv/PS3_DEMOS.tsv

set n=0
for /f "tokens=1,2,3,4,5,6,7,8 delims=	" %%A in (PS3_GAMES.tsv) do (
set /a n+=1
set TID=%%A
set REG=%%B
set NAM=%%C
set NAM=!NAM:,=!
set URL=%%D
set RAP=%%E
set CID=%%F
set DATE=%%G
set SIZE=%%H

echo TitleID  : !TID!                              Line number: !n!
echo Region   : !REG!
echo Name     : !NAM!
if "!URL:~-4!"==".pkg" (
	if "!URL:~0,5!"=="http:" (
		echo URL      : !URL!
		) else (
		echo URL Error: !URL!
		echo !CID!,1,!NAM! - !URL! URL,TitleID: !CID:~7,9!; Region: !REG!,!RAP!,!URL! URL,!SIZE!,>>pkgi_games_MISSING_URL.txt
		set URL=
	)
)
set i=1
for /l %%I in (1, 1, 36) do (
	set count=!RAP:~%%I!
	if defined count set /a i+=1
)
if !i!==32 (
	for %%J in (a b c d e f) do set RAP=!RAP:%%J=%%J!
	echo RAP      : !RAP!
	) else (
	echo RAP      : !RAP!
	if "!RAP!"=="NOT REQUIRED" (
		set NAM=!NAM! - RAP !RAP!
		set RAP=0
	)
	if "!RAP!"=="UNLOCK/LICENSE BY DLC" (
		set NAM=!NAM! - RAP !RAP!
		set RAP=0
	)
	if "!RAP!"=="MISSING" (
		echo !CID!,1,!NAM! - !RAP! RAP,TitleID: !CID:~7,9!; Region: !REG!,!RAP! RAP,!URL!,!SIZE!,>>pkgi_games_MISSING_RAP.txt
		set RAP=
	)
)
set i=1
for /l %%K in (1, 1, 36) do (
	set count=!CID:~%%K!
	if defined count set /a i+=1
)
if !i!==36 (
	echo ContentID: !CID!
	) else (
	echo ContentID: !CID! - Incorrect
	echo !CID! - Incorrect ContentID,1,!NAM!,TitleID: !CID:~7,9!; Region: !REG!,!RAP!,!URL!,!SIZE!,>>pkgi_games_MISSING_CID.txt
	set RAP=
)
if "!DATE:~4,1!!DATE:~7,1!"=="--" (
	echo Date     : !DATE!
) else (
	echo Date     : Not Defined
	if not defined SIZE set SIZE=!DATE!
	if not defined SIZE set SIZE=0
)
echo.
if defined RAP (
	if defined URL echo !CID!,1,!NAM!,TitleID: !CID:~7,9!; Region: !REG!,!RAP!,!URL!,!SIZE!,>>pkgi_games.txt
	)
)
pause

Батник 2 с контрольной суммой SHA256:

@echo off
setlocal EnableDelayedExpansion
TITLE Database Parser NoPlayStation - http://nopaystation.com
mode con:cols=172
if exist pkgi_games_MISSING_URL.txt del \q pkgi_games_MISSING_URL.txt
if exist pkgi_games_MISSING_RAP.txt del \q pkgi_games_MISSING_RAP.txt
if exist pkgi_games_MISSING_CID.txt del \q pkgi_games_MISSING_CID.txt
if exist pkgi_games.txt del \q pkgi_games.txt

wget -O PS3_GAMES.tsv http://nopaystation.com/tsv/PS3_GAMES.tsv
::wget -O PS3_DLCS.tsv http://nopaystation.com/tsv/PS3_DLCS.tsv
::wget -O PS3_THEMES.tsv http://nopaystation.com/tsv/PS3_THEMES.tsv
::wget -O PS3_AVATARS.tsv http://nopaystation.com/tsv/PS3_AVATARS.tsv
::wget -O PS3_DEMOS.tsv http://nopaystation.com/tsv/PS3_DEMOS.tsv

set n=0
for /f "tokens=1,2,3,4,5,6,7,8 delims=	" %%A in (PS3_GAMES.tsv) do (
set /a n+=1
set TID=%%A
set REG=%%B
set NAM=%%C
set NAM=!NAM:,=!
set URL=%%D
set RAP=%%E
set CID=%%F
set DATE=%%G
set SIZE=%%H

echo TitleID  : !TID!                              Line number: !n!
echo Region   : !REG!
echo Name     : !NAM!
if "!URL:~-4!"==".pkg" (
	if "!URL:~0,5!"=="http:" (
		echo URL      : !URL!
		) else (
		echo URL Error: !URL!
		echo !CID!,1,!NAM! - URL Error,TitleID: !CID:~7,9!; Region: !REG!,!RAP!,URL Error - !URL!,!SIZE!,>>pkgi_games_MISSING_URL.txt
		set URL=
	)
)
set i=1
for /l %%I in (1, 1, 36) do (
	set count=!RAP:~%%I!
	if defined count set /a i+=1
)
if !i!==32 (
	for %%J in (a b c d e f) do set RAP=!RAP:%%J=%%J!
	echo RAP      : !RAP!
	) else (
	echo RAP      : !RAP!
	if "!RAP!"=="NOT REQUIRED" (
		set NAM=!NAM! - RAP !RAP!
		set RAP=0
	)
	if "!RAP!"=="UNLOCK/LICENSE BY DLC" (
		set NAM=!NAM! - RAP !RAP!
		set RAP=0
	)
	if "!RAP!"=="MISSING" (
		echo !CID!,1,!NAM! - !RAP! RAP,TitleID: !CID:~7,9!; Region: !REG!,!RAP! RAP,!URL!,!SIZE!,>>pkgi_games_MISSING_RAP.txt
		set RAP=
	)
)
set i=1
for /l %%K in (1, 1, 36) do (
	set count=!CID:~%%K!
	if defined count set /a i+=1
)
if !i!==36 (
	echo ContentID: !CID!
	) else (
	echo ContentID: !CID! - Incorrect
	echo !CID! - Incorrect ContentID,1,!NAM!,TitleID: !CID:~7,9!; Region: !REG!,!RAP!,!URL!,!SIZE!,>>pkgi_games_MISSING_CID.txt
	set RAP=
)
if "!DATE:~4,1!!DATE:~7,1!"=="--" (
	echo Date     : !DATE!
) else (
	echo Date     : Not Defined
	if not defined SIZE set SIZE=!DATE!
	if not defined SIZE set SIZE=0
)
if defined URL (
	wget --spider --server-response -o SHA256.txt !URL! > nul
	for /f "tokens=1,2 delims= " %%M in (SHA256.txt) do (
		if [%%M]==[X-Agile-Checksum:] set SHA256=%%N
		if [%%M]==[Content-Length:] set SIZE=%%N
	)
	if defined SIZE echo Size     : !SIZE!
	if defined SHA256 echo SHA256   : !SHA256!
)
echo.
if defined RAP (
	if defined URL echo !CID!,1,!NAM!,TitleID: !CID:~7,9!; Region: !REG!,!RAP!,!URL!,!SIZE!,!SHA256!>>pkgi_games.txt
	)
)
del \q SHA256.txt
pause

P.S. Инструкция в шапке в спойлере.